读书会以太坊代币开发 (ERC20 标准)

jimi · 2018年06月24日 · 2492 次阅读

以太坊 ERC20 代币开发首先需要对以太坊,代币,ERC20,智能合约等以太坊代币开发中的基本概念有了解。根据我们的示例代码就可以发行自己的以太坊代币。

什么是 ERC20

可以把 ERC20 简单理解成以太坊上的一个代币协议，所有基于以太坊开发的代币合约都遵守这个协议。遵守这些协议的代币我们可以认为是标准化的代币，而标准化带来的好处是兼容性好。这些标准化的代币可以被各种以太坊钱包支持，用于不同的平台和项目。说白了，你要是想在以太坊上发行代币融资，必须要遵守 ERC20 标准。

ERC20 的标准接口是这样的:

contract ERC20 {  
    function name() constant returns (string name)  
    function symbol() constant returns (string symbol)  
    function decimals() constant returns (uint8 decimals)  
    function totalSupply() constant returns (uint totalSupply);  
    function balanceOf(address _owner) constant returns (uint balance);  
    function transfer(address _to, uint _value) returns (bool success);  
    function transferFrom(address _from, address _to, uint _value) returns (bool success);  
    function approve(address _spender, uint _value) returns (bool success);  
    function allowance(address _owner, address _spender) constant returns (uint remaining);  
    event Transfer(address indexed _from, address indexed _to, uint _value);  
    event Approval(address indexed _owner, address indexed _spender, uint _value);  
  }

name

返回 ERC20 代币的名字，例如” My test token”。

symbol

返回代币的简称，例如：MTT，这个也是我们一般在代币交易所看到的名字。

decimals

返回 token 使用的小数点后几位。比如如果设置为 3，就是支持 0.001 表示。

totalSupply

返回 token 的总供应量

balanceOf

返回某个地址 (账户) 的账户余额

transfer

从代币合约的调用者地址上转移_value 的数量 token 到的地址_to，并且必须触发 Transfer 事件。

transferFrom

从地址_from 发送数量为_value 的 token 到地址_to,必须触发 Transfer 事件。

transferFrom 方法用于允许合同代理某人转移 token。条件是 from 账户必须经过了 approve。这个后面会举例说明。

approve

允许_spender 多次取回您的帐户，最高达_value 金额。如果再次调用此函数，它将以_value 覆盖当前的余量。

allowance

返回_spender 仍然被允许从_owner 提取的金额。

后面三个方法不好理解，这里还需要补充说明一下，

approve 是授权第三方（比如某个服务合约）从发送者账户转移代币，然后通过 transferFrom() 函数来执行具体的转移操作。

账户 A 有 1000 个 ETH，想允许 B 账户随意调用他的 100 个 ETH，过程如下：

A 账户按照以下形式调用 approve 函数 approve(B,100)
B 账户想用这 100 个 ETH 中的 10 个 ETH 给 C 账户，调用 transferFrom(A, C, 10)
调用 allowance(A, B) 可以查看 B 账户还能够调用 A 账户多少个 token

后面两个是事件，事件是为了获取日志方便提供的。前者是在代币被转移时触发，后者是在调用 approve 方法时触发。

基于 ERC20 编写的一个代币合约

pragma solidity ^0.4.16;  
contract Token{  
    uint256 public totalSupply;  

    function balanceOf(address _owner) public constant returns (uint256 balance);  
    function transfer(address _to, uint256 _value) public returns (bool success);  
    function transferFrom(address _from, address _to, uint256 _value) public returns     
    (bool success);  

    function approve(address _spender, uint256 _value) public returns (bool success);  

    function allowance(address _owner, address _spender) public constant returns   
    (uint256 remaining);  

    event Transfer(address indexed _from, address indexed _to, uint256 _value);  
    event Approval(address indexed _owner, address indexed _spender, uint256   
    _value);  
}  

contract TokenDemo is Token {  

    string public name;                   //名称，例如"My test token"  
    uint8 public decimals;               //返回token使用的小数点后几位。比如如果设置为3，就是支持0.001表示.  
    string public symbol;               //token简称,like MTT  

    function TokenDemo(uint256 _initialAmount, string _tokenName, uint8 _decimalUnits, string _tokenSymbol) public {  
        totalSupply = _initialAmount * 10 ** uint256(_decimalUnits);         // 设置初始总量  
        balances[msg.sender] = totalSupply; // 初始token数量给予消息发送者，因为是构造函数，所以这里也是合约的创建者  

        name = _tokenName;                     
        decimals = _decimalUnits;            
        symbol = _tokenSymbol;  
    }  

    function transfer(address _to, uint256 _value) public returns (bool success) {  
        //默认totalSupply 不会超过最大值 (2^256 - 1).  
        //如果随着时间的推移将会有新的token生成，则可以用下面这句避免溢出的异常  
        require(balances[msg.sender] >= _value && balances[_to] + _value > balances[_to]);  
        require(_to != 0x0);  
        balances[msg.sender] -= _value;//从消息发送者账户中减去token数量_value  
        balances[_to] += _value;//往接收账户增加token数量_value  
        Transfer(msg.sender, _to, _value);//触发转币交易事件  
        return true;  
    }  


    function transferFrom(address _from, address _to, uint256 _value) public returns   
    (bool success) {  
        require(balances[_from] >= _value && allowed[_from][msg.sender] >= _value);  
        balances[_to] += _value;//接收账户增加token数量_value  
        balances[_from] -= _value; //支出账户_from减去token数量_value  
        allowed[_from][msg.sender] -= _value;//消息发送者可以从账户_from中转出的数量减少_value  
        Transfer(_from, _to, _value);//触发转币交易事件  
        return true;  
    }  
    function balanceOf(address _owner) public constant returns (uint256 balance) {  
        return balances[_owner];  
    }  


    function approve(address _spender, uint256 _value) public returns (bool success)     
    {   
        allowed[msg.sender][_spender] = _value;  
        Approval(msg.sender, _spender, _value);  
        return true;  
    }  

    function allowance(address _owner, address _spender) public constant returns (uint256 remaining) {  
        return allowed[_owner][_spender];//允许_spender从_owner中转出的token数  
    }  
    mapping (address => uint256) balances;  
    mapping (address => mapping (address => uint256)) allowed;  
}